内插法怎么用(内插法怎么用计算器)

插值法又称“内插法”，主要包括线性插 值、抛物线插值和拉格朗日插值等。其中的线 性插值法是指使用连接两个已知量的直线，来 确定在这两个已知量之间的一个未知量的值。相当于已知坐标（x0, y0）与（x1, y1），要得 到 x0 至 x1 区间内某一位置 x 在直线上的值， 如图 5-51 所示。

Excel 中的 TREND 函数和 FORECAST 函数都可以完成简单的线性插值计算。

图5-51线性插值法图示

简单的插值计算

线性插值法计算电阻值

图 5-52 所示，是某物体在不同温度下测 得的电阻值，需要使用插值法预测在某个指定 温度时的电阻值。

E2 单元格输入以下公式，计算结果为 21.0562。=TREND(B2:B5,A2:A5,D2)

TREND 函数的作用是根据已知 x 序列的值和 y 序列的值，构造线性回归直线方程，然 后根据构造好的直线方程，计算 x 值序列对应的 y 值序列。函数语法为：TREND(known_y's,[known_x's],[new_x's],[const])

第一参数指定已知关系 y=mx+b 中的 y 值集合。

第二参数指定已知关系 y=mx+b 中的 x 值集合。

第三参数指定需要函数 TREND 返回对应 y 值的新 x 值。

第四参数是一个逻辑值，如果为 TRUE 或省略，b 将按正常计算。如果为 FALSE，b 将被设为 0（零）。

图5-52插值法计算电阻值

本例中，TREND 函数的 y 值集合为 B2:B5 单元格区域的电阻值，x 值集合为 A2:A5 单 元格区域中的温度值，新 x 值为 D2 单元格中的温度值。TREND 函数省略第四参数，最终以 线性插值法计算出温度为 -194 度时对应的电阻值。

使用以下公式也可实现相同的计算。=FORECAST(D2,B2:B5,A2:A5)

FORECAST 函数的作用是根据现有的 x 值和 y 值，根据给定的 x 值通过线性回归来预测新的 y 值。函数语法如下。FORECAST(x, known_y's, known_x's)

第一参数是需要进行预测的数据点。

第二参数和第三参数分别对应已知的 y 值和 x 值。

FORECAST 函数的计算结果与 TREND 函数的结果相同。

分段插值计算

在插值计算中，取样点越多，插值结果的误差越小。分段线性插值是将与插值点靠近的 两个数据点使用直线连接，然后在直线上选取对应插值点的数。

分段线性插值法计算热力性质

图5-53 所示，是某热力公司热力性质对照表的部分内容，需要根据对照表中的数据， 以分段线性插值法计算在指定压力下各项热力性质的指标。

图5-53热力性质对照表

步骤1： K3 单元格输入以下公式，根据 A3 单元格的插值点在对照表中计算出等于或靠近该 插值点的位置，如图 5-54 所示。=MATCH(A3,A9:A179,1)

图5-54计算靠近该插值点的位置

MATHC 函数在 A9:A179 单元格区域中查询 A3 单元格中压力值所处的位置。A9:A179 单元格区域中的压力值是升序排列，并且 MATCH 函数第三参数设置为 1。因此在查询不到 具体的值时，将以小于查询值的最接近值进行匹配，并返回其相对位置。

步 骤 2： B3 单元格输入以下公式，向右复制填充到 I3 单元格，计算出各项热力性质指标，如 图 5-55 所示。=IF($A3=4,B179,TREND(OFFSET(B$8,$K3,0,2),OFFSET($A$8,$K3,0,2), $A3))

图5-55分段线性插值法计算热力性质

公式中用到了 OFFSET 函数，这个函数的作用是以指定的引用为参照，通过给定偏移 量得到新的引用，返回的引用可以为一个单元格或单元格区域。函数语法如下。OFFSET(reference,rows,cols,[height],[width])

第一参数偏移量的参照点，可以是一个单元格或是一个单元格区域的引用。

第二参数是相对于参照点要偏移的行数。如果偏移量的参照点是一个单元格区域时， 则以单元格区域的左上角单元格开始计算偏移量。如果参数为正数，表示从参照点开始 向下偏移。如果为负数，表示从参照点开始向上偏移。参数值为 0 或是省略参数值表示 不偏移。

第三参数是相对于参照点要偏移的列数。如果偏移量的参照点是一个单元格区域时，则 以单元格区域的左上角单元格开始计算偏移量。如果参数为正数，表示从参照点开始向右偏 移。如果为负数，表示从参照点开始向左偏移。参数值为 0 或是省略参数值表示不偏移。

第四参数用于指定新引用区域的行数，如果省略参数时，新引用区域的行数和参照点的 行数相同。

第五参数用于指定新引用区域的列数，如果省略参数时，新引用区域的列数和参照点的 列数相同。

多数情况下，OFFSET 函数的计算结果会作为其他函数的参数进行进一步的计算处理。如果偏移量超出了工作表边缘，将返回错误值 #REF!。

通过以下两组图示，可以更便于理解 OFFSET 函数的偏移方式。

如图 5-56 所示，使用以下公式返回对 D5 单元格的引用。=OFFSET(A1,4,3)

图5-56OFFSET 函数偏移图示 1

公式偏移过程：先确定以 A1 单元格作为偏移的参照点。

第二参数为 4，表示以 A1 为基点向下偏移 4 行，至 A5 单元格。

第三参数为 3，表示自 A5 单元格向右偏移 3 列，至 D5 单元格。

第四参数和第五参数省略，表示新引用范围的行列数和参照点的行列数相同，都为 1， 即一个单元格。

如图 5-57 所示，以下公式将返回对 D5:G8 单元格区域的引用。=OFFSET(A1,4,3,4,4)

图5-57OFFSET 函数偏移图示 2

公式偏移过程：先确定以 A1 单元格作为偏移的参照点。第二参数为 4，表示以 A1 为 基点向下偏移 4 行，至 A5 单元格。第三参数为 3，表示自 A5 单元格向右偏移 3 列，至 D5 单元格。第四参数和第五参数都为 4，表示以 D5 单元格为左上角，最终返回 4 行 4 列的引用， 即 D5:G8 单元格区域。

本例中，TREND函数的第一参数为“OFFSET(B$8,$K3,0,2)”返回的引用区域，作为 已知关系 y=mx+b 中的 y 值集合部分。

这部分公式中的 $K3，是 MATCH 函数根据 A3 单元格的插值点在对照表中计算出的靠 近或等于该插值点的位置。OFFSET 函数以 B$8 单元格为参照点，根据 $K3 单元格中的计 算结果确定向下偏移的行数。偏移列数为 0，即不偏移，新引用的行数为 2，最终在B列得到与插值点相邻的两个单元格的引用。

TREND 函数的第二参数为“OFFSET($A$8,$K3,0,2) ”返回的引用区域，作为已知关系 y=mx+b 中的 x 值集合部分。这部分公式的偏移过程与第一参数的偏移过程相同，以 $A$8 单元格为基点，偏移后最终得到与插值点相邻的两行一列的引用。也就是等于或靠近该插值 点的压力值所在单元格及随后与之相邻的一个单元格。

TREND 函数的第三参数为 $A3 单元格中指定的压力值，作为要返回对应 y 值的新 x 值。

TREND 函数以等于或靠近插值点的两个单元格作为要计算插值的分段点，使插值计算 的结果精度更高。

当公式向右复制时，“OFFSET(B$8,$K3,0,2)”部分分别返回不同列中的引用作为 y 值 集合，“OFFSET($A$8,$K3,0,2)”部分则始终引用 A 列中的数据作为 x 值集合，从而实现了 各项热力性质指标的插值计算。

对照表最后一行的压力值为 4，当 $A3 单元格中的压力值等于该数值时，OFFSET 函数 偏移后的范围会包含对照表下方的空白单元格，此时 TREND 函数会返回错误值。因此先使用 IF 函数对 $A3 单元格的压力值进行判断，如果等于 4，则返回对照表中最后一行对应的指标。

END

推荐阅读北京大学出版社Excel数据处理与分析应用大全